When_network_density_weakens_intention_action_alignment

; ------------------------------------------------------------------------------
; When Network Density Weakens Intention–Action Alignment:
; An Agent-Based Model of Financial Support Networks in Entrepreneurial Ecosystems
;
; Authors:
;
; Model description:
; This agent-based model simulates the dynamics of financial support networks
; within entrepreneurial ecosystems. Entrepreneurs form growth intentions based
; on attitudes, subjective norms, and perceived behavioral control, following the
; Theory of Planned Behavior.
; The model captures how network structure, particularly network density and the
; presence of venture-capital-backed peers, shapes access to venture capital and
; conditions the alignment between individual growth intentions and realized
; venture growth at the aggregate level.
;
; The model initializes with a population of entrepreneurs and a single venture
; capitalist (included primarily for visualization purposes and represented by
; a red node). Entrepreneurs shown in white represent the initial population with
; no growth-related behavior. Entrepreneurs shown in yellow indicate agents with
; high growth intention who are preparing to act. Entrepreneurs shown in green
; represent agents that have established a formal financial relationship with
; the venture capitalist.
;
; White links represent informal social relationships among entrepreneurs. Green
; links indicate formal financial relationships between entrepreneurs and the
; venture capitalist. Blue links indicate that an entrepreneur has applied for
; funding and is undergoing evaluation by the venture capitalist.
;
; ------------------------------------------------------------------------------


breed [entreps entrep] ; entrepreneurs
breed [vcs vc] ; venture capital firms

undirected-link-breed [entrep-links entrep-link] ; links between entrepreneurs
undirected-link-breed [both-links both-link] ; links between venture capital firms and entrepreneurs



;;;;;;;;;  1: VARIABLES    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

globals [
  
  number-entreps

  prob-invest ; probability of receiving funding

  ; GROWTH
  growth ; average number of entrepreneurs who obtain capital to develop their venture in a given time step
  g ; list storing the growth variable for each tick
  growth_mean ; mean of list g, representing a final outcome
  ;growth_sd ; standard deviation of list g

  ;;; POPULATION BEHAVIOR 
  pop-growth-intention ; mean growth intention of the entire population
  pgi ; list storing population growth intention
  pop_intention_mean ; mean of list pgi

  pcb ; mean perceived behavioral control of the population
  p ; list storing perceived control values
  pcb_mean ; mean of list p
  

  max-behav-aux; auxiliar variable
]

extensions [ nw ]

links-own ; 
[
  known ; knowledge-based relationship
  financial ; financial relationship
]

entreps-own [

  funds ; individual financial resources; start at 0, if interaction is successful funds increase by 100
  behavior ; entrepreneurial behavior
  intention ; entrepreneurial intention of the agent
  attitude ; agent’s attitude toward growth
  subjective-norm ; subjective norm perceived by the agent
  percep-control ; perceived behavioral control
  pf ; perceived power of the specific control factor (f: financial capital) to facilitate or inhibit behavior; constant over time
  motivation ; agent’s motivation derived from known entrepreneurs
  refunds ; number of times the agent has received funding

  my-neighbors ; immediate neighbors at one-link distance

  ;; Coefficients
  w1 ; weight of attitude
  w2 ; weight of subjective norm
  w3 ; weight of perceived behavioral control (w1 + w2 + w3 = 1)


 ; Relationship attributes
  monitoring-time ; time at which monitoring occurs to decide on further funding rounds and relationship continuation
  evaluation-time ; time required to evaluate whether funding is granted initially
  tie-to-vc ; equals 1 if linked to a VC through a successful funding relationship; financial ties may end while knowledge ties persist
  cycles

  behav-aux
  b0 ; auxiliary behavior indicator
  entreps-vc
  
]



vcs-own
[
  funds
]


;;;;;;;;; 2. SETUP   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to setup
  clear-all
  setup-globals
  setup-entreps
  setup-vcs
  setup-fsn
  reset-ticks
end 

to setup-globals
  
 set number-entreps 140
 set prob-invest 0.04

 ; POPULATION
 set pgi [] ; intention
 set p [] ; perceived control
 set g [] ; growth
end 

to setup-entreps 
  
;building-initial-net
 create-entreps number-entreps [
    set heading who * 360 / number-entreps
    setxy 0 0
    fd 60
    set color white
    set size 2
  ]
  
  ;; red regular: k vecinos
  ask entreps [
    let my-id who
    let half-k floor (connectivity / 2)
    let i 1

    while [i <= half-k] [
      let neighbor (my-id + i) mod number-entreps
      if not link-neighbor? turtle neighbor [
        create-entrep-link-with turtle neighbor
      ]
      set i i + 1
    ]
  ]

  ;; rewiring tipo Watts–Strogatz
  ask entrep-links [
    if random-float 1 < 1 [
      let source end1
      ask source [
        let candidates other entreps with [not link-neighbor? source]
        if any? candidates [
          let new-target one-of candidates
          ask myself [ die ]
          create-entrep-link-with new-target
        ]
      ]
    ]
  ]
  
  ask entrep-links
    [
      set known true
      set financial false
    ]
  
  ask entreps [
  
    set color white
    set shape "person"
    set size 3

    ; Set agent attributes
    set behavior 0
    set funds random-poisson 200
    set attitude random-normal 0.5 0.1 ; value between 0 and 1

    ; Perceived power of the specific control factor (f: financial capital) to facilitate or inhibit behavior
    ; Control belief regarding the presence or absence of resources and opportunities required to perform the behavior
    set pf 1
    set motivation 1
    set refunds 0

    set w1 random-float 1 ; value between 0 and 1
    set w2 random-float 1 ; value between 0 and 1
    set w3 random-float 1 ; value between 0 and 1

    ; Relationship attributes
    set evaluation-time 0
    set monitoring-time 0
    set tie-to-vc 0

  ]
end 

to setup-vcs

  create-vcs 1 [
  set color red
  set shape "circle"
  set size 6
  ]
end 

to setup-fsn ; financial support network initial condition
  ; A financial network is created between some entrepreneurs and VCs.
  ; The purpose is to generate initially connected entrepreneurs that trigger the system dynamics.

  ask up-to-n-of number-inter entreps ; number-inter = 10
  [
    create-both-link-with one-of vcs
    [
      set color green
      set known true
      set financial true
    ]

    set color green
    set funds funds + 100
    set refunds 1
    set behavior 1
    set monitoring-time 100
    set evaluation-time 0
    set tie-to-vc 1
    fd -40
  ]
end 

to go
  if ticks = 1000 [ stop ] ; stops the simulation
  intention-and-growth
  globals-outcome ; global outcome indicators
  global-indicators
  life
  tick
end 



; Growth intention and growth (access to financial capital) are computed
; as a combination of attitude, subjective norm, and perceived control over VC accessibility.

to intention-and-growth
  ; Intention is defined as I = Attitude + Subjective Norm + Perceived Behavioral Control

  ask entreps with [behavior = 0]  [ ; computed for entrepreneurs who have not accessed financial capital

   ; (0) Normalize coefficients of attitude, subjective norm, and perceived control so that nw1 + nw2 + nw3 = 1

    let nw1  (w1 / (w1 + w2 + w3))
    let nw2  (w2 / (w1 + w2 + w3))
    let nw3  (w3 / (w1 + w2 + w3))

 ; (1) Attitude
    ; Initialized at setup

 ; (2) Subjective norm

    let my-neighbors$ entrep-link-neighbors with [behavior = 1]

    let sum-my-neighbors$ count my-neighbors$

    ifelse(sum-my-neighbors$ > 0 )[
      set subjective-norm (motivation * sum-my-neighbors$ / count entrep-link-neighbors)
    ]
    [
      set subjective-norm 0
    ]

 ; (3) Perceived behavioral control

    set entreps-vc ((nw:turtles-in-radius 1) with [shape = "person"]) with [tie-to-vc = 1] ; entrepreneurs connected to a VC, excluding the VC itself

    ifelse any? entreps-vc
     [
      let sum-entreps-vc count entreps-vc

      ifelse(sum-entreps-vc > 0 )
                                 [
                                  set percep-control pf * sum-entreps-vc /
                                    (count ((nw:turtles-in-radius 1) with [shape = "person"]))
                                 ]
                                 [
                                   set percep-control 0
                                  ]
     ]
    [
      set percep-control 0 ; without neighbors connected to a VC, access to funding is not possible
    ]

    ; (4) Intention

    set intention nw1 * attitude + nw2 * subjective-norm + nw3 * percep-control

    ; Probability of behavioral activation
    set behav-aux intention * percep-control
  ]

 ; (5) Auxiliary behavior

  ask entreps with [behavior = 0][

      let max-entrep max-one-of entreps [behav-aux]
      ask max-entrep [set max-behav-aux behav-aux]
      ifelse max-behav-aux > 0 [
                               set b0 behav-aux / max-behav-aux
                              ]
                              [ set b0 0]

      ; Perceived control is required for behavior to occur
      let w logit b0 0.5 0.05 ; determines whether intention is sufficiently high

       if (random-float 1 < w) [ ; if w is high, the startup interacts with a VC
                            set color yellow ; indicates agents with high intention
                            set behavior 0.5 ; intermediate behavior: seeking funding
                            fd -20
                            ]
   ]

 ; Entrepreneurs with intermediate behavior attempt to obtain capital by interacting with VCs.
 ; This may result in successful growth (behavior = 1) or failure (behavior = 0).

  ask entreps with [behavior = 0.5] [dynamic-to-find-capital]

 ; Entrepreneurs who obtained capital may receive additional funding rounds if performance is satisfactory.
 ; VC monitoring determines whether funding continues or stops.

  ask entreps with [behavior = 1] [dynamic-end-financial]
end 

to-report logit [ my-intention pa1 pa2 ]
  ; pa1 = 0.5, pa2 = 0.05
  report 1.0 / (1.0 + exp( - ( my-intention - pa1) / pa2 ) )
end 

to globals-outcome

  ; GROWTH
   set growth count entreps with [behavior = 1 and intention > 0] ; number of successful entrepreneurs

  ; Mean growth intention of the population
  set pop-growth-intention mean [intention] of entreps with [intention > 0]

  ; Mean perceived behavioral control of the population
  set pcb mean [percep-control] of entreps with [intention > 0]
 
  ; Store variables in lists for each tick
  set g lput growth g
  set pgi lput pop-growth-intention pgi
  set p lput pcb p
end 

to global-indicators

  ; Temporal averages representing final outcomes
  set growth_mean mean g
  set pop_intention_mean mean pgi
  set pcb_mean mean p
end 

to dynamic-to-find-capital ; entrepreneurs with intermediate behavior (B = 0.5) actively seeking capital

  set entreps-vc ((nw:turtles-in-radius 1) with [color != red]) with [tie-to-vc = 1]

  if any? entreps-vc [

    if (monitoring-time = 0 and evaluation-time = 0) [

    set evaluation-time 11 ; evaluation delay before funding decision

    create-both-link-with one-of vcs
      [
        set color blue
        set known true
        set financial false
      ] ; establishes a knowledge-only relationship with the VC
    ]
  ]

  ; After evaluation, funding may be granted or denied
  if (evaluation-time = 1 and monitoring-time = 0) [
    ifelse (random-float 1 < prob-invest) [ ; funding is granted with given probability
      set monitoring-time 100
      set funds funds + 100
      set color green
      set behavior 1
      ask my-both-links [set financial true set color green] ; formal financial relationship
      set tie-to-vc 1
      fd -20
     ]
    [condition-b0] ; otherwise, the agent returns to behavior = 0
  ]
end 

to condition-b0 ; behavior returns to B = 0 while knowledge ties may persist
  set behavior 0
  set color white
  set monitoring-time 0
  set evaluation-time 0
  set size 3
  if tie-to-vc = 0 [ask my-both-links [die]]
  fd 20
end 

to dynamic-end-financial ; end of financial relationship after monitoring period
  if (monitoring-time = 0) [
  set behavior 0
  set color white
  set monitoring-time 0
  set evaluation-time 0
  set size 3
  set refunds 0
  ask my-both-links [set color blue set financial false]
  set tie-to-vc 1
  fd 40
  ]
end 

to life
ask entreps [
    ; One unit of funds is consumed at each tick
    if (funds > 0) [set funds funds - 1]
    if (evaluation-time > 0) [set evaluation-time evaluation-time - 1]
    if (monitoring-time > 0) [set monitoring-time monitoring-time - 1]

    if funds = 0 [ ; agent exit (firm failure)
    die
    ]

    while [count entreps with [color = green and intention = 0] < number-inter] [
      ask patch 0 0 [
      sprout-entreps (number-inter - count entreps with [color = green and intention = 0]) [
        fd 20
        new-inter
         ]
      ]]

    while [count entreps < number-entreps] [
      ask patch 0 0 [
       sprout-entreps (number-entreps - count entreps) [
        fd 60
        new-startup
         ]
      ]]
   ]
end 

to new-startup
   ; Initialize attributes of a new startup
     set color white
     set shape "person"
     set size 3
     set behavior 0
     set funds random-poisson 200

      set pf 1.0
      set motivation 1.0
      set attitude random-normal 0.5 0.1

      set refunds 0
      set cycles 0

     set w1 random-float 1
     set w2 random-float 1
     set w3 random-float 1

     set tie-to-vc 0
     create-entrep-links-with n-of (2 * connectivity) other entreps
end 

to new-inter
   ; Initialize attributes of a new entrepreneur with prior VC access
     set color green
     set shape "person"
     set size 3
     set behavior 1
     set funds 100 + random-poisson 200

      set pf 1.0
      set motivation 1.0
      set attitude random-normal 0.5 0.1

      set refunds 1
      set cycles 0

     set w1 random-float 1
     set w2 random-float 1
     set w3 random-float 1
     create-entrep-links-with n-of (2 * connectivity) other entreps

    create-both-link-with one-of vcs
    [
      set color green
      set known true
      set financial true
    ]

    set monitoring-time 100
    set evaluation-time 0
    set tie-to-vc 1
end 


; END OF CODE