;; breeds: boars, deer, wolves, men.
breed [deer a-deer] ;;
breed [boar a-boar] ;;
breed [wolves wolf] ;;
breed [men a-man] ;; men are meant to be hunters
turtles-own [energy age]  ;; all breeds have energy and age
men-own [motivation]
patches-own [countdown];;
globals [week-of-year];

to setup
  clear-all
  set week-of-year 1

  ask patches [
      set pcolor one-of [ green brown ]
      ifelse pcolor = green
        [ set countdown grass-regrowth-time ]
      [ set countdown random grass-regrowth-time ] ; initialize grass regrowth clocks randomly for brown patches
    ]

  set-default-shape deer "deer"
  create-deer initial-number-deer [ ;; create the deer
    ;; then initialize their variables
    set color orange
    set size 1.5
    ;;set label-color blue
    ;;set energy 1 + random deer-max-initial-energy  ;; se pascolano:
    set energy random (2 * deer-gain-from-food)
    set age random 521 ;; initial age can be up to 10 years
    setxy random-xcor random-ycor
  ]

  set-default-shape wolves "wolf 7"
  create-wolves initial-number-wolves [ ;; create the wolves
    ;; then initialize their variables
    set color black
    set size 1
    set energy random (2 * wolf-gain-from-food)
    set age random 270 ;; initial age can be up to 5 years
    setxy random-xcor random-ycor
  ]

  set-default-shape boar "boar"
  create-boar initial-number-boar [ ;; create the boar
    ;; then initialize their variables
    set color blue
    set size 1.5
    ;;set label-color black
    ;;set energy 1 + random boar-max-initial-energy  ;; se pascolano:
    set energy random (2 * boar-gain-from-food)
    set age random 521 ;; initial age can be up to 10 years
    setxy random-xcor random-ycor
  ]

   set-default-shape men "person"
  create-men initial-number-hunters [ ;; create the (regular) hunters
    ;; then initialize their variables
    set color yellow
    set size 2
    ;;set label-color black
    set energy  1000
    set motivation 10
    setxy random-xcor random-ycor
  ]

  reset-ticks
end 

to go
  if not any? turtles [ stop ]
  ask deer [
    move
    set energy energy - 1  ;; deer lose energy as they move
    eat-grass-deer
    advance-age
    reproduce-deer
    death
  ]

  ask boar [
    move
    set energy energy - 1  ;; boars lose energy as they move
    eat-grass-boar
    advance-age
    reproduce-boar
    death
  ]

  ask wolves [
    move
    set energy energy - 1  ;; wolves lose energy as they move
;    catch-deer
;    catch-boar
    catch-prey
    advance-age
    reproduce-wolves
    death
  ]

  ask men [
    move
    ;;set energy energy - 1  ;; hunters lose energy as they move
    set motivation motivation - 1  ;; hunters want to hunt as time passes
    if shoot-deer = TRUE [ ;; if deer hunting is allowed then
      if count deer > deer-cut-off [hunt-deer]] ;; if there are enough deer then hunt deer
    if shoot-boar = TRUE [ ;; if boar hunting is allowed then
      if count boar > boar-cut-off [hunt-boar]] ;; if there are enough boar then hunt boar
    if shoot-wolf = TRUE [ ;; if wolf control is allowed then
      if count wolves > wolves-cut-off [poach]] ;; if there are too many wolves then kill some
    stay-home ;; if you feel you've hunted enough, take a break
  ]

  ask patches [
    grow-grass
  ]

ifelse week-of-year = 52               ;; check if year is over
  [set week-of-year 1]                 ;; then restart count of weeks
  [set week-of-year week-of-year + 1]  ;; otherwise advance 1 week

tick
end 

to grow-grass  ; patch procedure
  ; countdown on brown patches: if you reach 0, grow some grass
  if pcolor = brown [
    ifelse countdown <= 0
      [ set pcolor green
        set countdown grass-regrowth-time ]
      [ set countdown countdown - 1 ]
  ]
end 

to move  ;; turtle procedure
  rt random 50
  lt random 50
  fd 1
end 

to advance-age ;; turtle procedure
  set age age + 1
end 

to eat-grass-deer
  if pcolor = green [
    set pcolor brown
    set energy energy + deer-gain-from-food
  ]
end 

to eat-grass-boar
  if pcolor = green [
    set pcolor brown
    set energy energy + boar-gain-from-food
  ]
end 

to reproduce-deer  ;; deer procedure
  if age > 52 [
    if energy > 2 * deer-gain-from-food [
    if random-float 100 < deer-reproduce [  ;; throw "dice" to see if you will reproduce
    set energy (energy / 2)                ;; divide energy between parent and offspring
    hatch 1 [ set age 0
      rt random-float 360 fd 1 ]   ;; hatch an offspring and move it forward 1 step
  ]]]
end 

to reproduce-boar  ;; boar procedure
  if age > 52 [
    if energy > 2 * boar-gain-from-food [
    if random-float 100 < boar-reproduce [  ;; throw "dice" to see if you will reproduce
    set energy (energy / 2)                ;; divide energy between parent and offspring
    hatch 1 [ set age 0
      rt random-float 360 fd 1 ]   ;; hatch an offspring and move it forward 1 step
  ]]]
end 

to reproduce-wolves  ;; wolf procedure
  if age > 52 [
    if energy > 2 * wolf-gain-from-food [
    if random-float 100 < wolf-reproduce [  ;; throw "dice" to see if you will reproduce
    set energy (energy / 2)               ;; divide energy between parent and offspring
    hatch 1 [ set age 0
      rt random-float 360 fd 1 ]  ;; hatch an offspring and move it forward 1 step
  ]]]
end 

to catch-prey  ;; wolves procedure
    ifelse (any? boar-here and not any? deer-here)
        [let prey one-of boar-here                    ;; grab a random boar
          if prey != nobody                             ;; did we get one?  if so,
        [ ask prey [ die ]                          ;; kill it
          set energy energy + wolf-gain-from-food ] ;; get energy from eating
         ]
      [ifelse (any? deer-here and not any? boar-here)
        [let prey one-of deer-here                    ;; grab a random deer
         if prey != nobody                             ;; did we get one?  if so,
        [ ask prey [ die ]                          ;; kill it
         set energy energy + wolf-gain-from-food ] ;; get energy from eating
         ]
      [if (any? deer-here and any? boar-here)
          [let prey one-of boar-here                    ;; If both boar and deer available, boar is the preferre target
           if prey != nobody                             ;; did we get one?  if so,
             [ ask prey [ die ]                          ;; kill it
               set energy energy + wolf-gain-from-food ] ;; get energy from eating
             ]
  ]]
end 

to death  ;; turtle procedure
  ;; when energy dips below zero, die
  if energy < 0 [ die ]
  ifelse breed = wolves                          ;; when age grows above a maximum, die
    [if age > 521 [ die ]]                       ;; wolves die younger than herbivores
     [if age > 1042 [ die ]]
end 

to hunt-deer
  if week-of-year >= 52 - hunting-season [          ;; check if hunting is open
  if count deer > deer-cut-off [
      let prey one-of deer-here                     ;; grab a random prey > one-of preylist ???
      if prey != nobody                             ;; did we get one?  if so,
      [ ask prey [ die ]                          ;; kill it
        set motivation motivation + 1 ]]] ;; get appagated
end 

to hunt-boar
  if week-of-year >= 52 - hunting-season [          ;; check if hunting is open
  if count boar > boar-cut-off [
      let prey one-of boar-here                     ;; grab a random prey > one-of preylist ???
      if prey != nobody                             ;; did we get one?  if so,
      [ ask prey [ die ]                            ;; kill it
        set motivation motivation + 1 ]]]           ;; get appagated
end 

to poach
  ifelse count wolves > wolves-cut-off ;; implement counter in the interface ;;
[let prey one-of wolves-here                         ;; grab
  if prey != nobody                                  ;;
    [ask prey [ die ]]]
    [let prey one-of wolves-here                     ;; grab
     if prey != nobody [                             ;;
     if random-float 100 < wolf-poaching-rate [      ;; throw "dice" to see if hunter is willing to poach
        ask prey [ die ]]]]
end 

to stay-home
  if motivation > 20
  [hide-turtle
  wait 0.2
  show-turtle]
end